ich habe mir mal die Mühe gemacht und ein kleines Batch-Script geschrieben, welche eine Audio-Aufnahme von Bosmon in MP3 umwandelt und anschließend per E-Mail versendet. Somit weiß man unterwegs, was los ist.
Folgende Programme werden benötigt:
- Lame = http://www.heise.de/download/lame-mp3-encoder.html
- Blat = http://sourceforge.net/projects/blat/fi ... 20Version/
- Sleep = http://www.sleepcmd.com
Code: Alles auswählen
@ECHO OFF
chcp 1252
set mydate=%date:~-10,2%.%date:~-7,2%.%date:~-4%
set mytime=%time:~-11,2%:%time:~-8,2%:%time:~-5,2%
@REM ---------------------------------------------------------------
@REM > HIER WERDEN DIE LAME EINSTELLUNGEN VORGENOMMEN <
@REM > DIESER BEREICH MUSS ANGEPASST WERDEN <
@REM ---------------------------------------------------------------
@REM %1 = Kurzbeschreibung
@REM %2 = Adresse
@REM %3 = Jahr
@REM %4 = Monat
@REM %5 = Tag
@REM %6 = Stunde
@REM %7 = Minute
@REM %8 = Sekunde
set lame="C:\Scripting\lame.exe"
set lame_artist="Leitstelle Florian"
set lame_title="%1 - %5.%4.%3 - %6:%7 Uhr"
set lame_source="C:\Scripting\Soundfiles\%2_%3%4%5-%6%7%8.wav"
set lame_target="C:\Scripting\Soundfiles\%1_%3%4%5-%6%7%8.mp3"
@REM ---------------------------------------------------------------
@REM > HIER WERDEN DIE BLAT EINSTELLUNGEN VORGENOMMEN <
@REM > DIESER BEREICH MUSS ANGEPASST WERDEN <
@REM ---------------------------------------------------------------
set blat="C:\Scripting\blat.exe"
set blat_to="empfaengeradresse@emailhoster.tld"
set blat_from="senderadresse@emailhoster.tld"
set blat_user="Benutzername"
set blat_pw="Passwort"
set blat_smtp="smtp.emailhoster.tld"
set blat_subject="Sprechwunsch %1"
set blat_body="Es ist ein neuer Sprechwunsch vom Fahrzeug %1 eingegangen. Dieser ist im Anhang zu finden."
set blat_attach="C:\Scripting\Soundfiles\%1_%3%4%5-%6%7%8.mp3"
@REM ---------------------------------------------------------------
@REM > HIER WERDEN DIE SLEEP EINSTELLUNGEN VORGENOMMEN <
@REM > DIESER BEREICH MUSS ANGEPASST WERDEN <
@REM ---------------------------------------------------------------
set sleep="C:\Scripting\sleep.exe"
@REM ---------------------------------------------------------------
@REM > AB HIER BITTE NICHTS MEHR ÄNDERN!!! <
@REM ---------------------------------------------------------------
@REM ##############################################################################################
set sleeptime="5"
cls
ECHO Folgende Daten sind von Bosmon übergeben worden:
ECHO Einheit: %1
ECHO Adresse: %2
ECHO Jahr: %3
ECHO Monat: %4
ECHO Tag: %5
ECHO Stunde: %6
ECHO Minute: %7
ECHO Sekunde: %8
%sleep% %sleeptime% /quiet
cls
%lame% -V5 --tt %lame_title% --ta %lame_artist% %lame_source% %lame_target%
%sleep% %sleeptime% /quiet
cls
%blat% -to %blat_to% -f %blat_from% -u %blat_user% -pw %blat_pw% -server %blat_smtp% -s %blat_subject% -body %blat_body% -attach %blat_attach%
%sleep% %sleeptime% /quiet
cls
del %lame_source%
%sleep% %sleeptime% /quiet
Ich habe bei mir alles unter C:\Scripting\ gespeichert. In diesem Verzeichnis habe ich nun folgende Dateien:
- blat.dll
- blat.exe
- blat.lib
- blatdll.h
- lame.exe
- lame_enc.dll
- script.bat
- sleep.exe
Code: Alles auswählen
FMS:
nicht Negieren
Adresse: 12345678
Status: 5
Richtung: FZG -> LST
Code: Alles auswählen
C:\Scripting\Soundfiles\%Adresse%_%Jahr%%Monat%%Tag%-%Stunde%%Minute%%Sekunde%.wav
Eine weitere Aktion ist "Programm ausführen" mit der folgenden Pfadangabe:
Code: Alles auswählen
"C:\Scripting\Script.bat" %kurzbeschreibung% %adresse% %jahr% %monat% %tag% %stunde% %minute% %sekunde%
Auf diesem Wege bekomme ich jeden Sprechwunsch (Natürlich nur den, den ich haben will) auf mein Handy und weiß auf dem Weg zur Wache schon evtl was los sein könnte.
Greetz Xx